// 0,1
// South West
beginoutdoorscript;

variables;
short choice,i;

body;

beginstate INIT_STATE;
// This state called whenever this section is loaded into memory.
break;

beginstate START_STATE;
// Starting state of the section, called every turn the party 
// stands inside this section until you change the state.
break;

beginstate 10;
	if(get_flag(200,6) == 0)
	{	message_dialog("A trail has been carved into the cliff leading down. The trip down is a frightful one, a shear drop to your imminent deaths stretches out to one side. To the other is the reassuring presence of the cliff wall.","You count yourself as a brave group of adventurers, but needless to say you keep against the wall.");
		set_flag(200,6,1); }
break;

beginstate 11;
	if(get_flag(200,7) == 0)
	{	message_dialog("A path leads up into the mountains here. Unfortunately you can see that the road has been destroyed several miles uproad. The path is covered in debris, and you can see a cliff waiting on the other side.","");
		set_flag(200,7,1); }
break;

beginstate 12;
if(get_flag(200,8) == 1)
{	message_dialog("You already killed the guards up here, so the way back up will be easy.","");
	set_state_continue(14); }
if(get_flag(10,9) > 0)
{	message_dialog("The cliff is clear of sentries, you can climb up easily.","");
	set_state_continue(14); }
else set_state_continue(13);
break;

beginstate 13;
		reset_dialog();
		add_dialog_str(0,"You have reached an impasse. The road leading to the top of this cliff has collapsed, leaving you with a straight climb two hundred feet into the air if you hope to pass.",0);
		add_dialog_Str(1,"Even worse, you can see golems moving around on top of the cliff. You would be completely helpless as you climb, and an easy victim for them.",0);
		add_dialog_str(2,"So should you try the seemingly impossible and begin climbing?",0);
		add_dialog_choice(0,"Climb.");
		add_dialog_choice(1,"Turn back.");
		choice = run_dialog(1);
		if(choice == 1)
		{	message_dialog("You start climbing up the cliff. Things seem to be going very well, you make it about halfway up without hearing from the golems.","Evidently you haven't gone unseen. The golems wait until you're about fifty feet before unleashing a barrage of rocks and energy. You scramble down the cliff, but not unscathed.");
			i = 0;
			while(i <= 5)
			{	if(char_ok(i) == 1)
					damage_char(i,get_ran(6,10,25),4);
				i = i + 1; }
			end(); }
		if(choice == 2)
		{	message_dialog("You wisely turn back.","");
			end(); }
break;

beginstate 14;
	reset_dialog();
	add_dialog_str(0,"So do you climb up?",0);
	add_dialog_choice(0,"Climb.");
	add_dialog_choice(1,"Leave.");
	choice = run_dialog(0);
	if(choice == 1)
		out_move_party(32,28);
	if(choice == 2)
		end();
break;

beginstate 15;
	reset_dialog();
	add_dialog_str(0,"The path is now clear of guards, do you climb down?",0);
	add_dialog_choice(0,"Climb.");
	add_dialog_choice(1,"Leave.");
	choice = run_dialog(1);
	if(choice == 1)
		out_move_party(29,28);
	if(choice == 2)
		end();
break;

beginstate 16;
if(get_flag(10,9) == 0)
if(get_flag(200,8) == 0)
{	reset_dialog();
	add_dialog_str(0,"This path seems to be the only way down from Mountainwatch. If you want down, you'll have to get through a battalion of golems that is guarding the path. What do you choose to do?",0);
	add_dialog_choice(0,"Fight them.");
	add_dialog_choice(1,"Leave.");
	choice = run_dialog(0);
	if(choice == 1)
	{	create_out_spec_enc(0);
		message_dialog("The golems don't hesitate to fight you. You're going to have your work cut out for you.","");
		end(); }
	if(choice == 2)
	{	block_entry(1);
		end(); }
}
if(get_flag(250,9) > 0)
	if(get_flag(250,10) == 0)
		if(char_ok(4) == 1)
		{	message_dialog("Glup turns to you, _I suppose this means our adventures are over. Please, take me back to my village before you leave, I have a departing gift for you._","");
			set_flag(250,10,1); }
break;

beginstate 17;
	if(get_flag(200,9) == 0)
	{	message_dialog("A massive quarry has been dug here. You are surprised to see that it seems newly excavated, especially since no humans inhabitat these lands.","");
		set_flag(200,9,1); }
break;